/**
 * オプションの指定
 */
options {
    LOOKAHEAD = 1;          // 先読みトークン数
    STATIC = false;         // true にするとスタティックメソッドを生成
    UNICODE_INPUT = true;   // true にすると Unicode 入力を扱う
    DEBUG_PARSER = false;   // true にするとデバグ情報出力
}

/**
 * 作成する構文解析クラスの定義
 * PARSER_BEGIN (クラス名)
 * と
 * PARSER_END (クラス名)
 * の間に作成するクラスの main メソッドを記述する。
 */
PARSER_BEGIN (Parser)
package kc;

import java.util.*;
import java.io.*;

/**
 * Macro statements are as follows :
 *   <Main>   ::= "main" "(" ")" "{" { <Decl> | <State> } "}" EOF
 *   <Decl>   ::= "int" <NAME> { "," <NAME> } ";"
 *   <Name>   ::= NAME
 *   <State>  ::= <If> | <While> | <Output> | <Assgn> | "{" { <State> } "}"
 *   <If>     ::= "if" "(" <Exp> ")" <State>
 *   <While>  ::= "while" "(" <Exp> ")" <State>
 *   <Output> ::= "outputint" "(" <Exp> ")" ";"
 *   <Assgn>  ::= Name "=" <Exp> ";" 
 *   <Exp>    ::= <Term> { ( "+" | "-" ) <Term> }
 *   <Term>   ::= <Factor> { ( "*" | "/" ) <Factor> }
 *   <Factor> ::= NAME | INTEGER | "inputint" 
 * 
 * Execute as follows :
 * $ javac kc/Parser.java
 * $ java kc.Parser inputfile
 */
public class Parser {
    public static void main (String[] args) {
        try {
            Parser parser = new Parser (new FileReader (args[0]));
            parser.enable_tracing();      // デバグ情報収集
            parser.Main();
        } catch (Exception err_mes) {     // 構文エラーがあった場合
            System.out.println (err_mes); // エラーメッセージを出力
        }
        System.out.println ("finished");
    }
}
PARSER_END (Parser)

/**
 * 字句解析時変数の宣言
 * 字句解析時に必要な変数があればここで宣言する。
 */
TOKEN_MGR_DECLS : {}

/**
 * 空白文字の定義
 * 空白文字は
 * SKIP :
 * {
 *     <パターン>
 * }
 * の形で定義され、パターンには正規表現を用いることができる。
 */
SKIP : {
   <" " | "\t" | "\n" | "\r">
 | <"//" (~["\n", "\r"])* ["\n","\r"]>
 | <"/*"> : IN_COMMENT 
}
<IN_COMMENT> SKIP : {
   <~[]>
 | <"*/"> : DEFAULT
}

/**
 * トークンの定義
 * トークンは
 * TOKEN :
 * {
 *     <トークン名: パターン>
 * }
 * の形で定義され、パターンには正規表現を用いることができる。
 */
TOKEN : {
    <SEMICOLON:   ";">
    | <LPAREN:    "(">
    | <RPAREN:    ")">
    | <LBRACE:    "{">
    | <RBRACE:    "}">
    | <COMMA:     "," >
    | <ASSGN:     "=">
    | <ADD:       "+">
    | <SUB:       "-">
    | <MUL:       "*">
    | <DIV:       "/">
    | <INTEGER:   "0" | (["1"-"9"](["0"-"9"])*)>
    | <IF:        "if">
    | <WHILE:     "while">
    | <INT:       "int">
    | <MAIN:      "main">
    | <OUTPUTINT: "outputint">
    | <INPUTINT:  "inputint">
    | <NAME :     (["a"-"z"]|["A"-"Z"])(["0"-"9"]|["a"-"z"]|["A"-"Z"])*>
}

/**
 * <Main> ::= "main" "(" "{" { <Decl> } { <State> } "}" <EOF>
 */
void Main() :
{}
{
    "main" "(" ")" "{" ( Decl() )* ( State() )* "}" <EOF>
}

/**
 * <Decl> ::= "int" <NAME> { "," <NAME> }
 */
void Decl() :
{}
{
    "int" Name() ( "," Name() )*";"
}

/**
 * <Name> ::= NAME
 */
void Name() :
{}
{
    <NAME>
}

/**
 * <State>  ::= { <If> | <While> | <Output> | <Assgn> | "{" { <State> } "} }
 */
void State() :
{}
{
    If() | While() | Output() | Assgn() | "{" ( State() )* "}"
}

/**
 * <If>     ::= "if" "(" <Exp> ")" <State> 
 */
void If() :
{}
{
    "if" "(" Exp() ")" State()
}

/**
 * <While>  ::= "while" "(" <Exp> ")" <State> 
 */
void While() :
{}
{
    "while" "(" Exp() ")" State()
}

/**
 * <Output> ::= "outputint" "(" <Exp> ")" ;
 */
void Output() :
{}
{
    "outputint" "(" Exp() ")" ";"
}

/**
 * <Assgn>  ::= NAME "=" <Exp> ";"
 */
void Assgn() :
{}
{
    <NAME> "=" Exp() ";"
}

/**
 * <Exp>    ::= <Term> { ( "+" | "-" ) <Term> }
 */
void Exp() :
{}
{
    Term() ( ( "+" | "-" ) Term() )*
}

/**
 * <Term>   ::= <Factor> { ( "*" | "/" ) <Factor> }
 */
void Term() :
{}
{
    Factor() ( ( "*" | "/" ) Factor() )*
}

/**
 * <Factor> ::= NAME | INTEGER | "inputint"
 */
void Factor() :
{}
{
    <NAME>| <INTEGER> | "inputint"
}